¿Cómo Imprimir Agrupando en excel?

Tengo varias macros similares.

La siguiente agrupa por la columna F y crea una nueva hoja. Podrías adaptarla, en lugar de crear la hoja, que imprima.

Split Data based on Value in Row | MrExcel Message Board

Split data in sheets (sheets typically already created) | MrExcel Message Board

O la siguiente imprime en PDF:

macro to create text files | MrExcel Message Board

Si tienes dificultades para adaptar alguna de las macros. Entonces pon aquí ejemplos de tu información con imágenes. Y explica brevemente el contenido de la imagen y lo qué necesitas hacer.

Si tienes datos confidenciales, cámbialos por datos genéricos. Es importante que se vean las filas y las columnas de excel. Ejemplo:

traté de adaptar tus ejemplos pero no he tenido suerte.. 

La estructura del excel es la de la imagen, en la columna "F" es donde debo ir seleccionanso el nombre del profesional, imprimir y seleccionar el siguiente profesional y así con todos de la base de datos 

Te paso la macro:

Sub ImprimirProfesionales()
'Por Dante Amor
  Dim sh As Worksheet
  Dim c As Range
  Dim ky As Variant
  Dim lr As Long
  '
  Application.ScreenUpdating = False
  '
  Set sh = Sheets("Hoja1")
  If sh.AutoFilterMode Then sh.AutoFilterMode = False
  lr = sh.Range("F" & Rows.Count).End(3).Row
  '
  With CreateObject("scripting.dictionary")
    For Each c In sh.Range("F2:F" & lr)
      .Item(c.Value) = Empty
    Next c
    '
    For Each ky In .Keys
      sh.Range("A1:F" & lr).AutoFilter 6, ky
      sh.PrintOut
    Next ky
    '
  End With
  sh.ShowAllData
  Application.ScreenUpdating = True
End Sub

Avísame cualquier duda. No olvides valorar.